第四节   客户端实现SQL 查询

   由于在客户端不存在TQuery控件，似乎客户服务器模式是无法做SQL
查询的。但是，Delphi很好的解决了这个问题。事实上，只要客户端连接上
服务端应用程序，客户端的TClientDataSet就包含了一个名字为Provider
的属性，对应到服务器端DataSetProvider的所有默认属性和方法，其中
DataSetProvider有一个Options属性，只要让其中的poAllowCommandText
=true， 那么，DataSetProvider的poAllowCommandText就可以接受前台来
的SQL 命令，并传送给TQuery。
   可以看出，真正传递数据的是DataSetProvider的接口，所以，用这个
接口搭建传递SQL 的桥梁是必需的。
   客户端进行SQL 查询的方法是：

     ClientDataSet.Close;
     ClientDataSet.CommandText := 'SQL语句';
     ClientDataSet.Open;

      第五节   客户端查询服务器端的别名集

   在SQL 查询以前，用户往往需要制定查询哪个数据库，所以需要把服
务器上BDE 数据库别名（Alias ）设置数据抓到前台程序来
   具体做法是：

   首先，在服务器端建立一个TSession和一个TDataBase

   Session1属性：
   SessionName=Session1_4
   
   DataBase1属性：
   DataBaseName: 连接数据库名
   SessionName:  Session1_4  （SessionName值）

   TQurey 增加个属性
   SessionName:  Session1_4

   这样就可以用Session对象来管理数据源的信息了。
   为了传给客户端值
   
   View -> Type Library 显示接口窗口。
   右键 ITest125Server（具体根据设置名不同而不同） -> New ->
建立两个方法：
   
   GetDatabaseNames ，用以传下别名数据，其接口信息为：
         Return type :HRESULT
         Parameters
   name         type          modifier
 
   Param        VARIANT*      [out,retval]

   SetDatabaseName ， 用以接受客户机来的信息，其接口信息要求传入
三个信息。

        Return type :HRESULT
         Parameters
   name         type          modifier
 
   DBName       BSTR          [in]      ----传上来的别名
   UserName     BSTR          [in]
   Password     BSTR          [in]

   刷新（Refresh  Implementation）以后，就产生两个函数

function TTest125Server.GetDatabaseNames: OleVariant;
var
 I: Integer;
 DBNames: TStrings;
begin
 // 建立一个字符串数组存放BDE所有的数据库别名数据。
 DBNames := TStringList.Create;
 try
   // 利用Session控件取得当前BDE所有的数据库别名数据。
   Session1.GetDatabaseNames(DBNames);

   /// 建立一个变量数组给函数返回变量Result。
   Result := VarArrayCreate([0, DBNames.Count - 1], varOleStr);

   // 最后再把数据库别名数据指定给该变量数组。
   for I := 0 to DBNames.Count - 1 do
     Result[I] := DBNames[I];
 finally
   DBNames.Free;
 end;
end;

   上面的函数的关键除了取得BDE 数据库别名以外，还声明了一个变量数
组来存放数据库别名数据，所以用VarArrayCreate函数建立一个变量数组，
其中  参数1： 指定数组范围
     参数2： 数组数据类型，由于别名要通过DCOM传给前台，数据类型必
须设成varOleStr 才有效。

   第二个过程是客户机提供上来的联机数据。

procedure TTest125Server.SetDatabaseName(const DBName, UserName,
 Password: WideString);
begin
 try
   // 把前台传来的数据库别名、用户上线名称、用户上线密码
   // 等三项数据指定给TDatabase控件，并且执行联机的操作。

   Database1.Close;
   Database1.AliasName := DBName;
   if (UserName<>'') and (Password<>'') then begin
     Database1.Params.Values['PASSWORD'] := Password;
     Database1.Params.Values['USER NAME'] := UserName;
   end;
   Database1.Open;
 except
     // 如果联机时发生错误，则产生一个exception给前台程序
   // 前台程序将会利用到这个exception来判断是否要把输入上
   // 线数据的窗口激活。

   on E: EDBEngineError do
  raise Exception.Create('Password Required') ;
  end;
end;

（出处：DelphiFans.com）